最新內(nèi)容會更新在主站深入淺出區(qū)塊鏈社區(qū)
原文鏈接:如何通過以太坊智能合約來進(jìn)行眾籌（ICO）

本文從技術(shù)角度詳細(xì)介紹如何基于以太坊ERC20創(chuàng)建代幣的流程.

寫在前面

本文所講的代幣是使用以太坊智能合約創(chuàng)建，閱讀本文前，你應(yīng)該對以太坊、智能合約有所了解，如果你還不了解，建議你先看以太坊是什么

代幣Token

如果不那么追求精確的定義，代幣就是數(shù)字貨幣，比特幣、以太幣就是一個(gè)代幣。
利用以太坊的智能合約可以輕松編寫出屬于自己的代幣，代幣可以代表任何可以交易的東西，如：積分、財(cái)產(chǎn)、證書等等。
因此不管是出于商業(yè)，還是學(xué)習(xí)很多人想創(chuàng)建一個(gè)自己的代幣，先貼一個(gè)圖看看創(chuàng)建的代幣是什么樣子。

image

今天我們就來詳細(xì)講一講怎樣創(chuàng)建一個(gè)這樣的代幣。

ERC20 Token

也許你經(jīng)?？吹紼RC20和代幣一同出現(xiàn)， ERC20是以太坊定義的一個(gè)代幣標(biāo)準(zhǔn)。
要求我們在實(shí)現(xiàn)代幣的時(shí)候必須要遵守的協(xié)議，如指定代幣名稱、總量、實(shí)現(xiàn)代幣交易函數(shù)等，只有支持了協(xié)議才能被以太坊錢包支持。
其接口如下：

contract ERC20Interface {

    string public constant name = "Token Name";
    string public constant symbol = "SYM";
    uint8 public constant decimals = 18;  // 18 is the most common number of decimal places

    function totalSupply() public constant returns (uint);
    function balanceOf(address tokenOwner) public constant returns (uint balance);
    function allowance(address tokenOwner, address spender) public constant returns (uint remaining);
    function transfer(address to, uint tokens) public returns (bool success);
    function approve(address spender, uint tokens) public returns (bool success);
    function transferFrom(address from, address to, uint tokens) public returns (bool success);

    event Transfer(address indexed from, address indexed to, uint tokens);
    event Approval(address indexed tokenOwner, address indexed spender, uint tokens);
}

簡單說明一下：
name ： 代幣名稱
symbol： 代幣符號
decimals： 代幣小數(shù)點(diǎn)位數(shù)，代幣的最小單位， 18表示我們可以擁有 .0000000000000000001單位個(gè)代幣。
totalSupply() : 發(fā)行代幣總量。
balanceOf(): 查看對應(yīng)賬號的代幣余額。
transfer(): 實(shí)現(xiàn)代幣交易，用于給用戶發(fā)送代幣（從我們的賬戶里）。
transferFrom(): 實(shí)現(xiàn)代幣用戶之間的交易。
allowance(): 控制代幣的交易，如可交易賬號及資產(chǎn)。
approve(): 允許用戶可花費(fèi)的代幣數(shù)。

編寫代幣合約代碼

代幣合約代碼：

pragma solidity ^0.4.16;

interface tokenRecipient { function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) public; }

contract TokenERC20 {
    string public name;
    string public symbol;
    uint8 public decimals = 18;  // 18 是建議的默認(rèn)值
    uint256 public totalSupply;

    mapping (address => uint256) public balanceOf;  // 
    mapping (address => mapping (address => uint256)) public allowance;

    event Transfer(address indexed from, address indexed to, uint256 value);

    event Burn(address indexed from, uint256 value);


    function TokenERC20(uint256 initialSupply, string tokenName, string tokenSymbol) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);
        balanceOf[msg.sender] = totalSupply;
        name = tokenName;
        symbol = tokenSymbol;
    }


    function _transfer(address _from, address _to, uint _value) internal {
        require(_to != 0x0);
        require(balanceOf[_from] >= _value);
        require(balanceOf[_to] + _value > balanceOf[_to]);
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        balanceOf[_from] -= _value;
        balanceOf[_to] += _value;
        Transfer(_from, _to, _value);
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // Check allowance
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    function approveAndCall(address _spender, uint256 _value, bytes _extraData) public returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);
        balanceOf[msg.sender] -= _value;
        totalSupply -= _value;
        Burn(msg.sender, _value);
        return true;
    }

    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);
        require(_value <= allowance[_from][msg.sender]);
        balanceOf[_from] -= _value;
        allowance[_from][msg.sender] -= _value;
        totalSupply -= _value;
        Burn(_from, _value);
        return true;
    }
}

代碼的詳細(xì)解讀，請訂閱我的小專欄。

部署

在開發(fā)測試智能合約時(shí)，MetaMask和Remix Solidity IDE是兩個(gè)非常好用的工具，今天就用他們來完成部署。

1. 安裝和配置MetaMask請參考開發(fā)、部署第一個(gè)去中心化應(yīng)用，不同的上本文選擇了以太坊的測試網(wǎng)絡(luò)Ropsten，如果你沒有余額請點(diǎn)擊購買buy，進(jìn)入的網(wǎng)站可以送一些測試以太幣給你，配置好之后，界面應(yīng)該如下：
   
   image

2. 瀏覽器打開Remix Solidity IDE，復(fù)制以上源碼粘貼上，在右側(cè)選項(xiàng)參考如圖的設(shè)置：
   [圖片上傳失敗...(image-5bb9d7-1516621983166)]
   注意Environment和Account和MetaMask保持一致，然后選擇合約TokenERC20，填入你想要的發(fā)行量，名稱及代號，就可以創(chuàng)建合約了。
   這時(shí)MetaMask會彈出一個(gè)交易確認(rèn)框，點(diǎn)SUBMIT。待合約部署交易確認(rèn)之后，復(fù)制合約地址。

3. 打開Metamask界面，切換到TOKENS，點(diǎn)添加合約，出現(xiàn)如下對話框：

   
   
   image

填入剛剛復(fù)制的地址，點(diǎn)ADD，這時(shí)你就可以看到你創(chuàng)建的代幣了，如圖：

image

哈哈，你已經(jīng)完成了代幣的創(chuàng)建和部署(正式網(wǎng)絡(luò)和測試網(wǎng)絡(luò)部署方法一樣)，可以在Etherscan查詢到我們剛剛部署的代幣?？梢杂盟M(jìn)行ICO了，從此走上人生巔峰（玩笑話，不鼓勵大家發(fā)行無意義的代幣）。

代幣交易

由于MetaMask插件沒有提供代幣交易功能，同時(shí)考慮到很多人并沒有以太坊錢包或是被以太坊錢包網(wǎng)絡(luò)同步問題折磨，今天我用網(wǎng)頁錢包來講解代幣交易。

1. 進(jìn)入網(wǎng)頁錢包地址, 第一次進(jìn)入有一些安全提示需要用戶確認(rèn)。

2. 進(jìn)入之后，按照下圖進(jìn)行設(shè)置：

   
   
   image

3. 連接上之后，如圖

   
   
   image

需要添加代幣，填入代幣合約地址。

4. 進(jìn)行代幣轉(zhuǎn)賬交易

   
   
   image

在接下來的交易確認(rèn)也，點(diǎn)擊確認(rèn)即可。

5. 交易完成后，可以看到MetaMask中代幣余額減少了，如圖：

   
   
   image

代幣交易是不是很簡單，只要明白了交易流程，使用其他的錢包也是一樣的道理。

如果你在創(chuàng)建代幣的過程中遇到問題，我的知識星球可為大家解答問題。

參考文檔

• 代幣標(biāo)準(zhǔn)
• Create your own crypto-currency with ethereum

深入淺出區(qū)塊鏈 - 系統(tǒng)學(xué)習(xí)區(qū)塊鏈，打造最好的區(qū)塊鏈技術(shù)博客。