LOT|物聯(lián)網(wǎng) 溫度傳感器

文章結(jié)構(gòu)

<a id="1"></a>前言

前段時(shí)間從網(wǎng)上買(mǎi)了一個(gè)體重計(jì)，它自帶了無(wú)線上網(wǎng)的功能，能夠同步體重測(cè)量數(shù)據(jù)到網(wǎng)上。想到物聯(lián)網(wǎng)已經(jīng)有這么多產(chǎn)品了，于是就打算自己做一個(gè)物聯(lián)網(wǎng)溫度傳感器。要做一個(gè)物聯(lián)網(wǎng)的設(shè)備，不管是體重計(jì)還是溫度傳感器等等，首先要清楚物體是怎么聯(lián)網(wǎng)的。

其中一種方式是通過(guò) Wi-Fi 模塊進(jìn)行連接。配備有 Wi-Fi 模塊的設(shè)備，能夠搜索附近的無(wú)線熱點(diǎn)，通過(guò) Wi-Fi 用戶名和密碼連接 Wi-Fi。但是如何讓設(shè)備知道所要連接的 Wi-Fi 和密碼呢？

具體的方法可以參考這里：智能家居第一步： WiFi 設(shè)備怎么連上網(wǎng)。

由于我們要完成的是一個(gè)物聯(lián)網(wǎng)溫度傳感器，我們選擇一種相對(duì)簡(jiǎn)單、直接的方法：我們?cè)诔绦蚶锩嬷苯釉O(shè)定好所要連接的 Wi-Fi 和密碼，這樣就能讓傳感器聯(lián)網(wǎng)了。下面將會(huì)介紹具體的做法。

<a id="2"></a>物聯(lián)網(wǎng)溫度傳感器

物聯(lián)網(wǎng)溫度傳感器分為兩大部分。一是傳感器，用于采集和發(fā)送溫度數(shù)據(jù)；二是遠(yuǎn)程服務(wù)器，用于收集溫度數(shù)據(jù)和根據(jù)請(qǐng)求返回溫度數(shù)據(jù)。

<a id="21"></a>傳感器

對(duì)于傳感器部分，需要一下材料：

  1. ESP8266開(kāi)發(fā)板（附帶 Wi-Fi 模塊和電源模塊）;
  2. DS18B20（溫度傳感器）;
  3. 連接線（USB線、導(dǎo)線）、電腦;

<a id="211"></a>ESP8266

ESP8266是一個(gè)小型的 Wi-Fi 模塊，能夠建立 Wi-Fi 熱點(diǎn)和連接 Wi-Fi 熱點(diǎn)，并且能夠配置 Web Client 或 Web Server 。它在我們這個(gè)溫度傳感器中的作用就是，作為一個(gè) Web Client ，在通過(guò) Wi-Fi 聯(lián)網(wǎng)后，實(shí)時(shí)向遠(yuǎn)程服務(wù)器發(fā)送本地的（溫度）數(shù)據(jù)。

ESP8266有很多個(gè)型號(hào)，從 ESP-01 到 ESP-12F 。ESP-01 是最初的版本，它上面可用的 GPIO 引腳較少，而 ESP-12F 具有全部 GPIO 引腳。由于 ESP8266 的額定電壓是 3.3V，而 USB 的電壓是 5V ，因此如果要單獨(dú)使用 ESP8266 的話，就需要外接電源轉(zhuǎn)化模塊。

我們選用的是 ESP-12E NodeMCU 開(kāi)發(fā)板：

開(kāi)發(fā)板上集成了電源模塊，因此我們可以直接用 USB 給開(kāi)發(fā)板供電，來(lái)使用 ESP8266，而不需要額外的電源模塊。

開(kāi)發(fā)板上附帶有 CP2102（高度集成的 USB-UART 橋接器）因此我們只需要用一根 USB 線連接開(kāi)發(fā)板與電腦，就能實(shí)現(xiàn)供電和下載程序。CP2102 在 Mac 和 PC 有相應(yīng)的驅(qū)動(dòng)程序，安裝好驅(qū)動(dòng)程序后，連接電腦，電腦就能識(shí)別出它的串口號(hào)。在接下去的燒寫(xiě)固件和下載程序都需要用到這個(gè)串口。

將開(kāi)發(fā)板連上電腦后，接下去我們將燒寫(xiě)固件，并下載程序到 ESP8266 里。

<a id="2111"></a>燒寫(xiě)固件，調(diào)試開(kāi)發(fā)板

一、燒寫(xiě)固件

燒寫(xiě)固件（firmware）需要用到 ESP8266Flasher。

首先，從 nodemcu-firmware 選擇合適的固件，如：nodemcu_float_0.9.6-dev_20150704.bin 。

然后打開(kāi) ESP8266，在 "Config" 頁(yè)面選擇需要燒寫(xiě)的固件：

在 "Advanced" 頁(yè)面設(shè)置好波特率，如：115200，一般這一頁(yè)不需要修改。設(shè)置完成后，在 "Operation" 頁(yè)面選擇串口，點(diǎn)擊 "Flash" 進(jìn)行燒寫(xiě)。

二、調(diào)試開(kāi)發(fā)板

燒寫(xiě)完成后，我們需要驗(yàn)證固件是否燒寫(xiě)成功。關(guān)閉燒寫(xiě)程序，重新連接開(kāi)發(fā)板與計(jì)算機(jī)，打開(kāi)調(diào)試軟件，推薦使用 Tera Term。

初次打開(kāi) TeraTerm 需進(jìn)行簡(jiǎn)單配置，在 "Serial" 選擇相應(yīng)的串口，點(diǎn)擊 "OK" 進(jìn)入主界面，此時(shí)輸入：

print("hello world")

得到相應(yīng)如下：

至此，燒寫(xiě)的固件已經(jīng)運(yùn)行在開(kāi)發(fā)板中，下一步可以進(jìn)行程序的編寫(xiě)和下載。

<a id="2112"></a>用 Arduino 編程

在 Mac 和 PC 上都可以用 Arduino 為 ESP8166 編程。

一、配置 Arduino ESP8266 開(kāi)發(fā)平臺(tái)

ESP8266 里的程序是支持 Lua 語(yǔ)言的。但是直接寫(xiě) Lua 程序，然后通過(guò)其他的軟件把程序下載到開(kāi)發(fā)板上，這個(gè)過(guò)程并不容易。因?yàn)橄鄳?yīng)的開(kāi)發(fā)軟件并不好用，比如 ESPlorer，luatool，Lualoader。因此，我們選用 Arduino 來(lái)進(jìn)行編程。一是因?yàn)?Arduino 用的比較多，比較專(zhuān)業(yè)，二是因?yàn)?Arduino 軟件做的比較精致，上手相對(duì)容易一些。

Arduino 是開(kāi)源軟件，下載安裝完成后，在"Presences"->"Additional Board Manager URLs" 里填入 http://arduino.esp8266.com/stable/package_esp8266com_index.json

然后從 "Tools"->"Board"->"Boards Manager" 打開(kāi) Boards Manager。搜索并安裝 ESP8266 開(kāi)發(fā)平臺(tái)。安裝完成后，記得在 "Tools"->"Board" 菜單里選擇和你開(kāi)發(fā)板型號(hào)一致的開(kāi)發(fā)平臺(tái)。

對(duì)于 Arduino ESP8266 開(kāi)發(fā)平臺(tái)的配置還有疑問(wèn)的話，可以參考 esp8266/Arduino。

二、下載測(cè)試程序

連接開(kāi)發(fā)板與電腦，在 Arduino 里選擇相應(yīng)的串口。將以下程序下載到開(kāi)發(fā)板中，記得修改程序中 Wi-Fi 的名稱(chēng)和密碼：

// Import required libraries
#include "ESP8266WiFi.h"
// WiFi parameters
const char* ssid = "YourWifiName";
const char* password = "WifiPassword";
void setup(void)
{
// Start Serial
Serial.begin(9600);
Serial.print("Connecting");
// Connect to WiFi
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("");
Serial.println("WiFi connected");
// Print the IP address
Serial.println(WiFi.localIP());
}
void loop() {
}

下載完成后，程序會(huì)自動(dòng)運(yùn)行。打開(kāi) "Tools"->"Serial Monitor" 查看串口的狀態(tài)。在串口監(jiān)視器上，會(huì)顯示 Wi-Fi 的連接情況，一旦連接成功，就會(huì)打印出 IP 地址，如下圖：

到這一步，我們已經(jīng)完成了開(kāi)發(fā)板的調(diào)試和程序下載。接下去我們將把 DS18B20 與 ESP8266 結(jié)合，實(shí)時(shí)發(fā)送溫度數(shù)據(jù)到遠(yuǎn)程服務(wù)器。

<a id="212"></a>DS18B20

DS18B20是常用的溫度傳感器，具有體積小，硬件開(kāi)銷(xiāo)低，抗干擾能力強(qiáng)，精度高的特點(diǎn)。

DS18B20 有三個(gè)管腳：GND、DQ、VDD。GND 接地，VDD 接 +3.3V，溫度數(shù)據(jù)只靠 DQ 引腳傳輸。

我們選用的是帶有上拉電阻的 DS18B20 模塊，這樣就不必自己外接上拉電阻。

連線方式：

  1. NodeMCU 開(kāi)發(fā)板 3v3 -> DS18B20 VDD
  2. NodeMCU 開(kāi)發(fā)板 D1 -> DS18B20 DQ
  3. NodeMCU 開(kāi)發(fā)板 GND -> DS18B20 GND

為了讀取傳感器上的溫度數(shù)據(jù)，還需要在 Arduino 上安裝 DallasTemperature 庫(kù)。在 "Sketch" -> "Include Library" -> "Manage Libraries.." 中搜索 DallasTemperature 并安裝。

<a id="22"></a>遠(yuǎn)程服務(wù)器

<a id="221"></a>方案一：ThingSpeak

物聯(lián)網(wǎng)服務(wù)器可以選用現(xiàn)成的、也可以自己設(shè)計(jì)搭建。
提供物聯(lián)網(wǎng)服務(wù)的有 ThingSpeak，它提供了多種強(qiáng)大的物聯(lián)網(wǎng) API ，能夠滿足各種需求。這里我們簡(jiǎn)單介紹一下使用 Thingspeak 的物聯(lián)網(wǎng)方案。

首先需要在 ThingSpeak 上注冊(cè)帳號(hào)，獲取帳號(hào)的 API key。然后使用下面的程序（需要修改 API key 以及 Wi-Fi 名稱(chēng)和密碼）：

#include <OneWire.h>
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
#include <DallasTemperature.h>

#define ONE_WIRE_BUS D1

const char* host = "api.thingspeak.com"; // Your domain
String ApiKey = "EWWXFA64H1U55QFZ";
String path = "/update?key=" + ApiKey + "&field1=";

OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature DS18B20(&oneWire);

const char* ssid = "YourWifiName";
const char* pass = "WifiPassword";

char temperatureString[6];

void setup(void){
  Serial.begin(9600);
  Serial.println("");

  WiFi.begin(ssid, pass);
  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }

  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  DS18B20.begin();

}

float getTemperature() {
  float temp;
  do {
    DS18B20.requestTemperatures();
    temp = DS18B20.getTempCByIndex(0);
    delay(100);
  } while (temp == 85.0 || temp == (-127.0));
  return temp;
}

void loop() {

  float temperature = getTemperature();

  dtostrf(temperature, 2, 2, temperatureString);
  // send temperature to the serial console
  Serial.println(temperatureString);

  WiFiClient client;
  const int httpPort = 80;
  if (!client.connect(host, httpPort)) {
    Serial.println("connection failed");
    return;
  }

  client.print(String("GET ") + path + temperatureString + " HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" +
               "Connection: keep-alive\r\n\r\n");
  delay(500);

}

程序下載到開(kāi)發(fā)板后，運(yùn)行時(shí)，就會(huì)自動(dòng)讀取傳感器的溫度并上傳到 ThingSpeak 上。通過(guò) ThingSpeak 上數(shù)據(jù)讀取的 API，就能在任何一臺(tái)聯(lián)網(wǎng)的設(shè)備上獲得傳感器的實(shí)時(shí)溫度數(shù)據(jù)。

<a id="222"></a>方案二：自己搭建服務(wù)端

ThingSpeak 是現(xiàn)成的物聯(lián)網(wǎng)服務(wù)，不使用它的話，我們?nèi)绾巫约捍罱ㄗ约旱奈锫?lián)網(wǎng)服務(wù)端呢？

物聯(lián)網(wǎng)溫度傳感器的服務(wù)端主要由一下幾個(gè)部分構(gòu)成：

  1. 服務(wù)器主機(jī)
  2. 服務(wù)器程序
  3. 后臺(tái)數(shù)據(jù)庫(kù)

一、服務(wù)器主機(jī)

對(duì)與主機(jī)的選擇，我們選用的是云主機(jī)，在淘寶上就可以購(gòu)買(mǎi)到，選擇動(dòng)態(tài) IP 的云主機(jī)即可。

二、服務(wù)器程序

服務(wù)器程序可以使用 PHP 編寫(xiě)，這里是我編寫(xiě)的溫度傳感器服務(wù)器程序。程序中的 host 默認(rèn)是 localhost，可供本地調(diào)試使用，當(dāng)配合云主機(jī)使用時(shí)，需要改成云主機(jī)的地址。

如果是在 Mac 上調(diào)試服務(wù)器程序，推薦使用 MAMP。更多關(guān)于服務(wù)器程序的編寫(xiě)，可以參考另一篇文章PHP：構(gòu)建 JSON 數(shù)據(jù)接口的 Web 服務(wù)器。

三、后臺(tái)數(shù)據(jù)庫(kù)

只有主機(jī)和程序還不夠，還需要配置好后臺(tái)服務(wù)器。淘寶上購(gòu)買(mǎi)的云主機(jī)一般都配有 MySQL 數(shù)據(jù)庫(kù)。在數(shù)據(jù)庫(kù)中添加名為 temperature 的表。然后在表中添加以下字段：

結(jié)合服務(wù)器程序，就能根據(jù)接收的請(qǐng)求，進(jìn)行數(shù)據(jù)的存儲(chǔ)與讀取。

搭建完自己的服務(wù)端后，需要對(duì)上面的 Arduino 程序稍作修改，如下（需要修改 host 為自己的服務(wù)器地址或域名）：

#include <OneWire.h>
#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
#include <DallasTemperature.h>

#define ONE_WIRE_BUS D1

const char* host = "YourDomain.com"; // Your domain
String key = "lsw";
String path = "/temperature.php?key=" + key + "&query=set&value=";

OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature DS18B20(&oneWire);

const char* ssid = "test";
const char* pass = "149149149";

char temperatureString[6];

void setup(void){
  Serial.begin(9600);
  Serial.println("");
 
 boolean result = WiFi.softAP("ESPsoftAP_01", "lsw-soft-AP",1,true);
 WiFi.softAPdisconnect(true); 
  if(result == true){
    Serial.println("Ready");
  }else{
    Serial.println("Failed!");
  }
    
  WiFi.begin(ssid, pass);
  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }

  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  DS18B20.begin();

}

float getTemperature() {
  float temp;
  do {
    DS18B20.requestTemperatures();
    temp = DS18B20.getTempCByIndex(0);
    delay(100);
  } while (temp == 85.0 || temp == (-127.0));
  return temp;
}

void loop() {

  float temperature = getTemperature();

  dtostrf(temperature, 2, 2, temperatureString);
  // send temperature to the serial console
  Serial.println(temperatureString);

  WiFiClient client;
  const int httpPort = 80;
  if (!client.connect(host, httpPort)) {
    Serial.println("connection failed");
    return;
  }

  client.print(String("GET ") + path + temperatureString + " HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" +
               "Connection: keep-alive\r\n\r\n");
  delay(500);

}

將程序下載到開(kāi)發(fā)板中運(yùn)行，就能實(shí)時(shí)發(fā)送溫度數(shù)據(jù)到服務(wù)器上了。
實(shí)際運(yùn)行效果如下（其中所連接的 Wi-Fi 名稱(chēng)是 “test”）：

在 Arduino 串口監(jiān)視器里的顯示狀態(tài)

有任何疑問(wèn)的話，歡迎在下方評(píng)論區(qū)討論。

附上我的Github：LinShiwei (Lin Shiwei) · GitHub

最后編輯于 ：
?著作權(quán)歸作者所有,轉(zhuǎn)載或內(nèi)容合作請(qǐng)聯(lián)系作者
【社區(qū)內(nèi)容提示】社區(qū)部分內(nèi)容疑似由AI輔助生成，瀏覽時(shí)請(qǐng)結(jié)合常識(shí)與多方信息審慎甄別。
平臺(tái)聲明：文章內(nèi)容（如有圖片或視頻亦包括在內(nèi)）由作者上傳并發(fā)布，文章內(nèi)容僅代表作者本人觀點(diǎn)，簡(jiǎn)書(shū)系信息發(fā)布平臺(tái)，僅提供信息存儲(chǔ)服務(wù)。

相關(guān)閱讀更多精彩內(nèi)容

友情鏈接更多精彩內(nèi)容