一、什么是凹凸映射
當(dāng)我們要表現(xiàn)一個(gè)模型凹凸有致的時(shí)候，我們往往需要給這個(gè)模型添加許許多多的面來表現(xiàn)它的凹凸感，但是當(dāng)我們的模型的面數(shù)越多的時(shí)候?qū)τ阡秩緯r(shí)的性能開銷也就也大，所以這往往也是不太可取的。這是就提出了凹凸映射這種解決方法。凹凸映射的目的就是使用一張紋理來修改模型表面的法線，以便為模型提供更多的細(xì)節(jié)。PS:這種方法不會(huì)真的改變模型的頂點(diǎn)位置，只是然那個(gè)模型看起來好像凹凸不平。
二、實(shí)現(xiàn)方式
有兩種主要的方法可以用來進(jìn)行凹凸映射：
（1）使用高度紋理
高度圖中存儲(chǔ)的強(qiáng)度值，它用于表示模型表面局部的海拔高度。因此，顏色越淺表明該位置的表面越向外凸起，而顏色越深表明該位置越向里凹。這種方法的好處就是非常的直觀，我們可以從高度圖中明確的知道一個(gè)模型表面的凹凸情況，但缺點(diǎn)是計(jì)算更加復(fù)雜，在實(shí)時(shí)計(jì)算時(shí)不能直接的得到表面法線，而是需要由像素的灰度值計(jì)算而得，因此需要消耗更多的性能。
（2）使用法線紋理
什么是法線紋理？簡(jiǎn)單的來說就是將一個(gè)模型的法線信息（xyz）映射成紋理的顏色（rgb）值，并保存成一張紋理，那么這個(gè)紋理就是法線紋理。
法線紋理有什么用？將具有高細(xì)節(jié)的模型通過映射烘焙出法線貼圖，貼在低端模型的法線貼圖通道上，使之擁有法線貼圖的渲染效果，卻可以大大降低渲染時(shí)需要的面數(shù)和計(jì)算內(nèi)容，從而達(dá)到優(yōu)化動(dòng)畫渲染和游戲渲染的效果。簡(jiǎn)單說就是將高模的法線數(shù)據(jù)，運(yùn)用到低模的光照計(jì)算中，實(shí)現(xiàn)類似高模的渲染效果，同時(shí)還提高性能。
介紹法線紋理的文章：http://blog.sina.com.cn/s/blog_6084f5880102v2bi.html
https://blog.csdn.net/candycat1992/article/details/41605257
法線->顏色轉(zhuǎn)換公式 ?法線方向的范圍在[-1,1]，像素顏色的分量范圍為[0,1],所以：
pixel = (normal ?+ 1) / 2
normal = pixel * 2 -1
既然要記錄法線的信息那么必須要確定法線信息是相對(duì)于那個(gè)空間坐標(biāo)系的。
（1）世界空間坐標(biāo)系下
將模型在世界空間坐標(biāo)系的法線信息保存在紋理中，這么做在使用的時(shí)候直接讀取，無需矩陣轉(zhuǎn)換。但是這樣做有非常大的局限性。當(dāng)模型進(jìn)行平移，旋轉(zhuǎn)等操作時(shí)，模型的在世界坐標(biāo)系下的法線數(shù)據(jù)也會(huì)變化，那么之前法線紋理中的信息將不在是正確的法線信息了。
（2）模型空間坐標(biāo)系下
在模型空間坐標(biāo)系下的法線紋理，實(shí)現(xiàn)簡(jiǎn)單，更加直觀，在紋理坐標(biāo)的縫合處和尖銳的邊角部分，可見的縫隙較少。當(dāng)模型的法線信息不會(huì)受模型的平移旋轉(zhuǎn)等影響，但是當(dāng)模型進(jìn)行縮放等操作時(shí)不能等到正確的法線信息
（3）切線空間坐標(biāo)系下
什么是切線空間？
對(duì)于模型的每個(gè)頂點(diǎn)，它都有一個(gè)屬于自己的切線空間，這個(gè)切線空間的原點(diǎn)就是該頂點(diǎn)本身，而Z軸是頂點(diǎn)的法線方向（n），X軸是頂點(diǎn)的切線方向（t），而Y軸可由法線和切線的叉積而得，而被稱為副切線或副法線。
切線空間下的法線紋理看起來幾乎全部都是藍(lán)色的，這是因?yàn)?，每個(gè)法線方向所在的坐標(biāo)空間是不一樣的，即是表面每點(diǎn)各自的切線空間。這種法線問紋理其實(shí)就是存儲(chǔ)了每個(gè)點(diǎn)在各自的切線空間的法線擾動(dòng)方向，也就是說，如果一個(gè)點(diǎn)的法線方向不變，那么在他的切線空間中，新的法線方向就是Z軸方向，即值是（0，0，1），經(jīng)過映射后存儲(chǔ)在紋理里就對(duì)應(yīng)了RGB（0.5，0.5，1）淺藍(lán)色。而這個(gè)顏色就是法線紋理中大片的藍(lán)色。這些藍(lán)色實(shí)際上說明頂點(diǎn)的大部分法線是何模型本身法線一樣的，不需要改變。
優(yōu)點(diǎn)：
（1）自由度高。模型空間下的法線紋理記錄的是絕對(duì)法線信息，僅可用于創(chuàng)建它時(shí)的那個(gè)模型，而應(yīng)用到其他模型上效果就完全錯(cuò)誤了，而切線空間下的法線紋理記錄的是相對(duì)法線信息，可以應(yīng)用到一個(gè)完全不同的網(wǎng)格上，也可以得到一個(gè)合理的結(jié)果。
（2）可進(jìn)行UV動(dòng)畫?？梢砸苿?dòng)一個(gè)紋理的UV坐標(biāo)來實(shí)現(xiàn)一個(gè)凹凸移動(dòng)的效果，水，火山熔巖
（3）可以重用法線紋理
（4）可壓縮。由于切線空間下法線紋理都是正方向的，因此我們可以存儲(chǔ)XY方向，而推導(dǎo)出Z方向。而模型空間下的法線紋理由于每個(gè)方向都有可能，因此必須存儲(chǔ)3個(gè)方向的值，不可壓縮。
實(shí)現(xiàn)：
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
Shader "Unity Shaders Book/Chapter 7/Normal Map In Tangent Space"
{
Properties
{
_Color ("Color Tint",Color) = (1,1,1,1)
_MainTex ("Texture", 2D) = "white" {}
//法線紋理
_BumpMap ("Normal Map",2D) = "dump" {}
// 控制凹凸程度
_BumpScale ("Bump Scale",Float) = 1.0
_Specular ("Specular",Color) = (1,1,1,1)
_Gloss ("Gloss",Range(8.0,256)) = 20
}
SubShader
{
Tags { "LightMode"="ForwardBase" }
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v
{
float4 vertex : POSITION;
float3 normal : Normal;
//頂點(diǎn)切線方向
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
float3 lightDir : TEXCOORD1;
float3 viewDir :TEXCOORD2;
};
v2f vert (a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
// 計(jì)算副切線
//float3 binormal = cross(normalize(v.normal),normalize(v.tangent.xyz)) * v.tangent.w;
//切線空間矩陣
//float3x3 rotation = float3x3(v.tangent.xyz,binormal,v.normal);
//內(nèi)置函數(shù)
TANGENT_SPACE_ROTATION;
// 光源在切線空間下的方向
o.lightDir = mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
//視角在切線空間下的方向
o.viewDir = mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
fixed3 tangentLightDir = normalize(i.lightDir);
fixed3 tangentViewDir = normalize(i.viewDir);
//采樣法線紋理
fixed4 packedNormal = tex2D(_BumpMap,i.uv.zw);
// 切線空間法向量
fixed3 tangentNormal;
// 如果沒有標(biāo)記為"Normal map"
//tangentNormal.xy = (packedNormal.xy * 2 - 1) * _BumpScale;
//tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));
//如果標(biāo)記為"Normal map"，可以使用內(nèi)置函數(shù)
tangentNormal = UnpackNormal(packedNormal);
tangentNormal.xy = tangentNormal.xy * _BumpScale;
tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));
// 在切線空間中計(jì)算光照
fixed3 albedo = tex2D(_MainTex,i.uv.xy).rgb * _Color.rgb;
//環(huán)境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
//漫反射光
fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(tangentNormal,tangentLightDir));
//高光反射
fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(tangentNormal,halfDir)),_Gloss);
return fixed4(ambient + diffuse + specular,1.0);
}
ENDCG
}
}
Fallback "Specular"
}
